Статьи и справочные
материалы

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<data>
<group gr_id="0" gr_name="На стороне клиента">
   <item id="0" name="Javascript">
      Безусловно, король браузерных сценариев.
   </item>
   <item id="1" name="Actionscript">
      Постоянно развивающийся язык программирования flash-приложений.
      Вместе с серверными скрипами становится удивительно мощным средством интерактивности
      и представления данных.
   </item>
</group>
<group gr_id="1" gr_name="На стороне сервера">
   <item id="2" name="PHP">
      Самый распространенный скриптовый язык программирования серверных сценариев.
   </item>
   <item id="3" name="Perl">
      Абориген программирования на стороне сервера. Несколько сложный синтаксис, но
      удивительная гибкость.
   </item>
</group>
</data>

import mx.utils.Delegate; // подключаем Delegate class
class MyXml {
   var file:String; // адрес/имя xml-файла
   private var _xml:XML = null; // загруженный обьект xml
   public var _data:Object = null; // результирующий объект с данными
   // конструктор класса (аргумент - имя файла):
   public function MyXml(f:String) {
      this.file = f;
      this._xml = new XML(); // создаем объект xml
      // игнорировать текстовые узлы, содержащие только пробельные символы:
      this._xml.ignoreWhite = true;
      // указываем область действия обработчику:
      this._xml.onLoad = Delegate.create(this, xmlParser);
      this._xml.load(this.file); // начинаем загрузку xml-документа
   }
   private function xmlParser(success):Void {
      // метод load возвражает булевое значение - успешность загрузки:
      if (success) {
         this._data = new Object(); // инициализируем объект для данных
         var group = this._xml.firstChild.firstChild; // берем указатель на первый элемент
         while (group) { // и в цикле пробегаем по всем остальным
            var gr_id = group.attributes.gr_id;
            this._data[gr_id] = new Object();
            this._data[gr_id]['gr_name'] = group.attributes.gr_name;
            this._data[gr_id]['items'] = new Object;
            var item = group.firstChild; // первый ребенок группы
            while(item) { // цикл по детям
               var id = item.attributes.id;
               this._data[gr_id]['items'][id] = new Object();
               this._data[gr_id]['items'][id]['name'] = item.attributes.name;
               // для текстового нода в АС2 нужно брать firstChild, а потом уже nodeValue:
               this._data[gr_id]['items'][id]['description'] = item.firstChild.nodeValue;
               item = item.nextSibling;
            }
            group = group.nextSibling;
         }
      }
      // вызываем внешнюю функцию для распечатки (читай - использования) полученных данных,
      // параметр - прошла ли загрузка успешно
      _root.printXmlData(success);
   }
}

import MyXml // подключаем класс
var myxml:MyXml = new MyXml('????.xml'); // создаем экземпляр - объект myxml
function printXmlData(succ:Boolean):Void {
   if (!succ) {
      trace('Возникла ошибка при попытке загрузить xml');
   }else {
      // распечатываем наш объект с помощью двух вложенных циклов
      for (var gr_id in myxml._data) {
         trace(myxml._data[gr_id]['gr_name'] + ' [' + gr_id + ']');
         for (var id in myxml._data[gr_id]['items']) {
            trace('--' + myxml._data[gr_id]['items'][id]['name'] + ' [' + id + ']');
            trace('--' + myxml._data[gr_id]['items'][id]['description']);
         }
      }
   }
}